rule "When there is a fire turn on the sprinkler"
when
    Fire($room : room)
    $sprinkler : Sprinkler(room == $room, on == false)
then
    modify($sprinkler){setOn(true)};
    System.out.println("Turn on the sprinkler for room " + $room.getName());
end

rule "When the fire is gone turn off the sprinkler"
when
    $room : Room()
    $sprinkler : Sprinkler(room == $room, on == true)
    not Fire(room == $room)
then
    modify($sprinkler){setOn(false)};
    System.out.println("Turn off the sprinkler for room " + $room.getName());
end

rule "Raise the alarm when we have one or more fires"
when
    exists Fire()
then
    insert(new Alarm());
    System.out.println("Raise the alarm");
end

rule "Cancel the alarm when all the fires have gone"
when
    not Fire()
    $alarm : Alarm()
then
    retract($alarm);
    System.out.println( "Cancel the alarm" );
end

rule "Status output when things are ok"
when
    not Alarm()
    not Sprinkler(on == true)
then
    System.out.println("Everything is ok");
end
            

// 房间
public class Room {
    private String name;  //房间名
    // getter and setter
}

// 灭火器
public class Sprinkler {

    private Room room;   //所属房间

    private boolean on;  //是否打开

    public Sprinkler(Room room){
        this.room = room;
    }
    // getter and setter
}

// 火灾
public class Fire {
    private Room room; //发生火灾的房间
    // getter and setter
}

// 警报
public class Alarm {
}
        

KnowledgeBuilder kbuilder = KnowledgeBuilderFactory.newKnowledgeBuilder();
kbuilder.add(ResourceFactory.newClassPathResource("rules/disaster.drl"), ResourceType.DRL);
if (kbuilder.hasErrors()) { //脚本是否有错误
    System.err.println(kbuilder.getErrors().toString());
    return;
}

KnowledgeBase kbase = KnowledgeBaseFactory.newKnowledgeBase();
kbase.addKnowledgePackages(kbuilder.getKnowledgePackages());

StatefulKnowledgeSession ksession = kbase.newStatefulKnowledgeSession();

//四个房间: 厨房, 卧室, 办公室, 客厅
String[] names = new String[]{"kitchen", "bedroom", "office", "livingroom"};
Map<String, Room> name2room = new HashMap<>();
for (String name : names) {
    Room room = new Room(name);
    name2room.put(name, room);
    ksession.insert(room);
    Sprinkler sprinkler = new Sprinkler(room);
    ksession.insert(sprinkler);     //将数据模型插入上下文
}

// Everything is ok
ksession.fireAllRules();

// kitchen and office is firing
Fire kitchenFire = new Fire( name2room.get( "kitchen" ) );
Fire officeFire = new Fire( name2room.get( "office" ) );
FactHandle kitchenFireHandle = ksession.insert( kitchenFire );
FactHandle officeFireHandle = ksession.insert( officeFire );
ksession.fireAllRules();

// fire is put out
ksession.retract( kitchenFireHandle )
ksession.retract( officeFireHandle );
ksession.fireAllRules();

ksession.dispose();